filevalid

Checks that a file can be read at initialisation or performance time.

Returns 1 if the sound file exists and is readable, or 0 if not.

Syntax

ir filevalid ifilcod
kr filevalid ifilcod

Initialization

ifilcod -- sound file to be queried

ir -- return code (1 if the sound file ifilcod can be read).

Performance

kr -- return code (1 if the sound file ifilcod can be read).

Examples

Here is an example of the filevalid opcode. It uses the file filevalid.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o filevalid.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs = 1

instr 1
Sfile     strget    p4
ivld      filevalid Sfile

if ivld>0 then
asig      diskin2   Sfile, 1
          outs      asig, asig
else
          printf_i  "Audiofile '%s' does not exist!\n", 1, Sfile
endif
endin

</CsInstruments>
<CsScore>

i 1 0 3 "frox.wav";file does not exist!!!
i 1 + 3 "fox.wav" ;but this one certainly does...

e
</CsScore>
</CsoundSynthesizer>

The output should include a line like this:

Audiofile 'frox.wav' does not exist!

See also

Sound File Queries

Credits

Author: Matt Ingalls
July 2010

New in Csound version 5.13