filter2

General purpose custom filter.

Performs filtering using a transposed form-II digital filter lattice with no time-varying control. The filter coefficients implement the following difference equation:

\[ (1) y(n) = b_0 x[n] + b_1 x[n-1] + ... + b_M x[n-M] - a_1 y[n-1] - ... - a_N y[n-N] \]

the system function for which is represented by:

\[ H(z) = \frac{B(z)}{A(z)} = \frac{b_0 + b_1 z^{-1} + ... + b_M z^{-M}}{1 + a_1 z^{-1} + ... + a_N z^{-N}} \]

Syntax

ares filter2 asig, ibcoefs, iacoefs, ib0, ib1, ..., ibM, ia1, ia2, ..., iaN
kres filter2 ksig, ibcoefs, iacoefs, ib0, ib1, ..., ibM, ia1, ia2, ..., iaN

Initialization

ibcoefs -- number of feedforward coefficients including b0.

iacoefs -- number of feedback coefficients

ib0, ... ibM -- feedforward coefficients including b0.

ia1, ... iaN -- feedback coefficients

At initialization the number of zeros and poles of the filter are specified along with the corresponding zero and pole coefficients. The coefficients must be obtained by an external filter-design application such as Matlab and specified directly or loaded into a table via GEN01.

Performance

The filter2 opcodes perform filtering using a transposed form-II digital filter lattice with no time-varying control.

Since filter2 implements generalized recursive filters, it can be used to specify a large range of general DSP algorithms. For example, a digital waveguide can be implemented for musical instrument modeling using a pair of delayr and delayw opcodes in conjunction with the filter2 opcode.

Examples

A first-order linear-phase lowpass FIR filter operating on a k-rate signal:

k1 filter2 ksig, 2, 0, 0.5, 0.5   ;; k-rate FIR filter

Here is another example of the filter2 opcode. It uses the file filter2.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac   ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o filter2.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1  ; 2 saw waves of which one is slightly detuned

ib1   = p5  
ivol  = p6                              ;volume to compensate                                               
kcps  init cpspch(p4)
asig1 vco2 .05, kcps                    ;saw 1
asaw1 filter2 asig1, 1, 1, 1, ib1       ;filter 1 
asig2 vco2 .05, kcps+1                  ;saw 2                      
asaw2 filter2 asig2, 1, 1, 1, ib1       ;filter 2
aout  = (asaw1+asaw2)*ivol              ;mix
      outs aout, aout

endin
</CsInstruments>
<CsScore>

i 1 0 4 6.00 -.001 5    ;different filter values
i 1 + 4 6.00 -.6   2    ;and different volumes
i 1 + 4 6.00 -.95 .3    ;to compensate
e
</CsScore>
</CsoundSynthesizer>

See also

Specialized Filters: Other filters

Credits

Author: Michael A. Casey
M.I.T.
Cambridge, Mass.
1997

New in version 3.47