Skip to content

midipolyaftertouch

Gets a MIDI polyphonic aftertouch value.

midipolyaftertouch is designed to simplify writing instruments that can be used interchangeably for either score or MIDI input, and to make it easier to adapt instruments originally written for score input to work with MIDI input.

In general, it should be possible to write instrument definitions that work identically with both scores and MIDI, including both MIDI files and real-time MIDI input, without using any conditional statements, and that take full advantage of MIDI voice messages.

Note that correlating Csound instruments with MIDI channel numbers is done using the massign opcode for real-time performance,. For file-driven performance, instrument numbers default to MIDI channel number + 1, but the defaults are overridden by any MIDI program change messages in the file.

Syntax

midipolyaftertouch xpolyaftertouch, xkey [, ilow] [, ihigh]

Initialization

ilow (optional) -- optional low value after rescaling, defaults to 0.

ihigh (optional) -- optional high value after rescaling, defaults to 127.

Performance

xpolyaftertouch -- returns MIDI polyphonic aftertouch of the selected note during MIDI activation, remains unchanged otherwise.

xkey -- specifies the MIDI key to read from. It normally should be set to the note number that the instrument instance is playing.

If the instrument was activated by MIDI input, the opcode overwrites the value of xpolyaftertouch with the corresponding value from MIDI input. If the instrument was NOT activated by MIDI input, the value remains unchanged.

This enables score p-fields to receive MIDI input data during MIDI activation, and score values otherwise.

📝 Adapting a score-activated Csound instrument.

See the MIDI interop opcodes section for details on adapting score driven instruments for MIDI or vice-versa.

Examples

Here is an example of the midipolyaftertouch opcode. It uses the file midipolyaftertouch.csd.

Example of the midipolyaftertouch opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac    -M1  ;;;realtime audio out and midi in 
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o midipolyaftertouch.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1;midi keyboard and score are used

midinoteoncps p4, p5                            ;puts MIDI key translated to cycles per second into p4, and MIDI velocity into p5

kafter  init 127                                ;full open                              
midipolyaftertouch  kafter, 1
printk2 kafter                                  ;display the key value when it changes and when key is pressed

kvel = p5/127                                   ;scale midi velocity to 0-1
kenv madsr 0.5, 0.8, 0.8, 0.5                   ;amplitude envelope multiplied by
ain  pluck kenv*kvel, p4, p4, 2, 1              ;velocity value                 
asig moogvcf2 ain, 300+(kafter*100), .5         ;use value of aftertouch to control frequency of filter
     outs  asig, asig                           ;base freq of filter = 300 Hz

endin
</CsInstruments>
<CsScore>
f 0 30  ;runs for 30 seconds
f 2 0 4096 10 1 ;sine wave

i 1 0 2 440 100 ;play these notes from score as well
i 1 + 2 1440 100
e

</CsScore>
</CsoundSynthesizer>

Its output should include lines like:

i1   127.00000
i1    20.00000
i1    44.00000

See also

MIDI/Score Interoperability

Credits

Author: Michael Gogins

New in version 4.20