Skip to content

ˆ

“Power of” operator.

Arithmetic operators perform operations of change-sign (negate), don't-change-sign, logical AND logical OR, add, subtract, multiply and divide. Note that a value or an expression may fall between two of these operators, either of which could take it as its left or right argument, as in

\[ a + b * c. \]

In such cases three rules apply:

  1. \(*\) and \(/\) bind to their neighbors more strongly than \(+\) and \(-\). Thus the above expression is taken as:
    \(a + (b * c)\) with \(*\) taking \(b\) and \(c\) and then \(+\) taking \(a\) and \(b * c\).

  2. \(+\) and \(-\) bind more strongly than &&, which in turn is stronger than ||:
    \(a \;\&\&\; b - c \;||\; d\) is taken as \((a \;\&\&\; (b - c))\;||\; d\)

  3. When both operators bind equally strongly, the operations are done left to right:
    \(a - b - c\) is taken as \((a - b) - c\)

Parentheses may be used as above to force particular groupings.

The operator ˆ raises \(a\) to the \(b\) power. \(b\) may not be audio-rate. Use with caution as precedence may not work correctly. See pow. (New in Csound version 3.493.)

Syntax

a ^ b  (b not audio-rate)

where the arguments \(a\) and \(b\) may be further expressions.

Examples

Here is an example of the ˆ operator. It uses the file raises.csd.

Example of the ˆ operator.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if RT audio input is needed too
; For Non-realtime ouput leave only the line below:
;-o ^.wav        ; output to audio file
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1 ; Lo-Fi sound

kpow      = 10                                          ;exponent
kbase     line 1, p3, 2.2                               ;vary the base
kQuantize = kbase^kpow
kQuantize = kQuantize*0.5                               ;half the number of steps for each side of a bipolar signal
printk2   kQuantize
asig      diskin2 "fox.wav", 1, 0, 1                    ;loop the fox
asig      = round(asig * kQuantize) / kQuantize         ;quantize and scale audio signal
          outs asig, asig  

endin
</CsInstruments>
<CsScore>

i1 0 19.2

e
</CsScore>
</CsoundSynthesizer>

Its output should include lines like these:

i1     0.50000
i1     0.50021
i1     0.50042
......
i1  1327.49320
i1  1327.74465

See also

Arithmetic and Logic Operations