sleighbells

Semi-physical model of a sleighbell sound.

It is one of the PhISEM percussion opcodes. PhISEM (Physically Informed Stochastic Event Modeling) is an algorithmic approach for simulating collisions of multiple independent sound producing objects.

Syntax

ares sleighbells kamp, idettack [, inum] [, idamp] [, imaxshake] [, ifreq] \
                 [, ifreq1] [, ifreq2]

Initialization

idettack -- period of time over which all sound is stopped

inum (optional) -- The number of beads, teeth, bells, timbrels, etc. If zero, the default value is 32.

idamp (optional) -- the damping factor, as part of this equation:

damping_amount = 0.9994 + (idamp * 0.002)

The default damping_amount is 0.9994 which means that the default value of idamp is 0. The maximum damping_amount is 1.0 (no damping). This means the maximum value for idamp is 0.03.

The recommended range for idamp is usually below 75% of the maximum value.

imaxshake (optional, default=0) -- amount of energy to add back into the system. The value should be in range 0 to 1.

ifreq (optional) -- the main resonant frequency. The default value is 2500.

ifreq1 (optional) -- the first resonant frequency. The default value is 5300.

ifreq2 (optional) -- the second resonant frequency. The default value is 6500.

Performance

kamp -- Amplitude of output. Note: As these instruments are stochastic, this is only an approximation.

Examples

Here is an example of the sleighbells opcode. It uses the file sleighbells.csd.

<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac      ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o sleighbells.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1


instr 1

idamp = p4
asig  sleighbells .7, 0.01, 32, idamp, 0.55
      outs asig, asig

endin
</CsInstruments>
<CsScore>

i 1 0.00 0.25 0 ;short sound
i 1 0.30 0.25
i 1 0.60 0.25
i 1 0.90 0.25
i 1 1.20 0.25
i 1 1.50 1   .3 ;longer sound
i 1 1.80 0.25 0 ;short sound again
i 1 2.10 0.25
i 1 2.40 0.25
i 1 2.70 0.25
i 1 3.00 0.25
e

</CsScore>
</CsoundSynthesizer>

See Also

Models and Emulations

Credits

Author: Perry Cook, part of the PhISEM (Physically Informed Stochastic Event Modeling)
Adapted by John ffitch
University of Bath, Codemist Ltd.
Bath, UK

New in Csound version 4.07

Added notes by Rasmus Ekman on May 2002.