Skip to content

trigger

Informs when a krate signal crosses a threshold.

Syntax

kout trigger ksig, kthreshold, kmode

Performance

ksig -- input signal

kthreshold -- trigger threshold

kmode -- can be 0 , 1 or 2

Normally trigger outputs zeroes: only each time ksig crosses kthreshold trigger outputs a 1. There are three modes of using ktrig:

  • kmode = 0 - (down-up) ktrig outputs a 1 when current value of ksig is higher than kthreshold, while old value of ksig was equal to or lower than kthreshold.
  • kmode = 1 - (up-down) ktrig outputs a 1 when current value of ksig is lower than kthreshold while old value of ksig was equal or higher than kthreshold.
  • kmode = 2 - (both) ktrig outputs a 1 in both the two previous cases.

Examples

Here is an example of the trigger opcode. It uses the file trigger.csd.

Example of the trigger opcode.
 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
<CsoundSynthesizer>
<CsOptions>
; Select audio/midi flags here according to platform
-odac     ;;;realtime audio out
;-iadc    ;;;uncomment -iadc if realtime audio input is needed too
; For Non-realtime ouput leave only the line below:
; -o trigger.wav -W ;;; for file output any platform
</CsOptions>
<CsInstruments>

sr = 44100
ksmps = 32
nchnls = 2
0dbfs  = 1

instr 1

kmtr lfo 1, 1, 1                        ;triangle wave
kmode = p4
ktr  trigger kmtr, .5, kmode
     printk2  ktr
     schedkwhen ktr, 0, 3, 2, 0, .3


endin

instr 2                                            

aenv linseg 0,p3*.1,1,p3*.3,1,p3*.6,0   ;envelope
a1   poscil .3*aenv, 1000, 1
     outs a1, a1

endin
</CsInstruments>
<CsScore>
f 1 0 16384 10 1        ;sine 

i 1 0 3 0               ;down-up
i 1 4 3 2               ;down-up & up=down

e
</CsScore>
</CsoundSynthesizer>

See also

Sensing and Control: Tempo and Sequencing

Credits

Author: Gabriel Maldonado
Italy

New in Csound version 3.49